Sql type

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
use "ffi"
use "debug"

trait SQLType
  """
  The most portable implementation of ODBC when reading and writing across
  the various database vendors has been as textual data via a buffer.

  Given this, we have implemented our SQL Datatypes in two halves - a
  "front-end" class, and this back-end SQLType.

  This class is responsible for allocating, binding, reallocating,
  reading, and writing the buffers with the database.

  The front-end class is responsible for translating the data to and
  from the native pony datatype.

  You should only need to refer to this trait if you are implementing
  a missing SQL datatype.

  ## Implemented ODBC Types:

  * SQLBigInteger
  * SQLFloat
  * SQLInteger
  * SQLReal
  * SQLSmallInteger
  * SQLVarchar
  """

  fun \nodoc\ ref get_boxed_array(): CBoxedArray
  fun \nodoc\ ref set_boxed_array(v: CBoxedArray)

  fun \nodoc\ ref get_err(): SQLReturn val
  fun \nodoc\ ref set_err(err: SQLReturn val)

  fun \nodoc\ ref alloc(size: USize): Bool =>
    get_boxed_array().alloc(size)

  fun \nodoc\ ref null() =>
    get_boxed_array().null()

  fun \nodoc\ ref reset(): Bool =>
    """
    Zeros the buffer and resets the field that defines the length of
    data written.
    """
    get_boxed_array().reset()

  fun \nodoc\ ref string(): String iso^ ? =>
    """
    Returns the written contents of the buffer as a string
    """
    get_boxed_array().string()?

  fun \nodoc\ ref array(): Array[U8] iso^ ? =>
    """
    Returns the written contents of the buffer as an array.
    """
    get_boxed_array().array()?

  fun \nodoc\ ref _write(str: String val): Bool =>
    """
    Writes the string into the provided buffer. If the string is
    larger than the buffer then it will FAIL, not re-allocate.

    (We can't reallocate, just in case this buffer is already bound
    to a query already)
    """
    get_boxed_array().write(str)

  fun \nodoc\ ref _write_array(arr: Array[U8] val): Bool =>
    """
    Writes the string into the provided buffer. If the string is
    larger than the buffer then it will FAIL, not re-allocate.

    (We can't reallocate, just in case this buffer is already bound
    to a query already)
    """
    if (not get_boxed_array().write_array(arr)) then return false end
    true

  fun \nodoc\ ref bind_parameter(h: ODBCHandleStmt tag, col: U16): SQLReturn val =>
    if (not _bind_parameter(h, col)) then
      return get_err()
    end
    get_err()

  fun \nodoc\ ref _bind_parameter(h: ODBCHandleStmt tag, col: U16): Bool =>
    var ba: CBoxedArray = get_boxed_array()
    set_err(
      ODBCFFI.resolve(
        ODBCFFI.pSQLBindParameter_varchar(
          h,
          col,
          1,
          1,
          -1,
          ba.alloc_size.u64(),
          0,
          ba.ptr,
          ba.alloc_size.i64(),
          ba.written_size)
      )
    )
    is_success()

  fun \nodoc\ ref is_success(): Bool =>
    match get_err()
    | let x: SQLSuccess => true
    else
      false
    end

  fun \nodoc\ ref realloc_column(h: ODBCHandleStmt tag, size: USize, col: U16): SQLReturn val =>
    """
    Reallocates the buffer to be populated by the database when data
    is fetched and rebinds the new buffer to the column.
    """
    set_boxed_array(CBoxedArray .> alloc(size))
    bind_column(h, col)

  fun \nodoc\ ref bind_column(h: ODBCHandleStmt tag, col: U16): SQLReturn val =>
    if (not _bind_column(h, col)) then
      return get_err()
    end
    get_err()

  fun \nodoc\ ref _bind_column(h: ODBCHandleStmt tag, col: U16): Bool =>
    var ba: CBoxedArray = get_boxed_array()
    set_err(
      ODBCFFI.resolve(
        ODBCFFI.pSQLBindCol_varchar(h, col, 1, ba.ptr, ba.alloc_size.i64(), ba.written_size)))
    is_success()

  fun \nodoc\ ref is_null(): Bool =>
    get_boxed_array().is_null()