Tx commit error

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
class val TxCommitError
  """
  Error committing a transaction.
  """
  let _verdict: TxCommitVerdict
  let _diag: DiagChain

  new val create(verdict': TxCommitVerdict, diag': DiagChain =
    recover val Array[DiagRecord] end) =>
    _verdict = verdict'
    _diag = diag'

  fun verdict(): TxCommitVerdict => _verdict

  fun string(): String iso^ =>
    recover iso
      let s = String
      s.append("TxCommitError: ")
      s.append(_verdict.string())
      try
        let rec = _diag(0)?
        s.append(" [")
        s.append(rec.sqlstate)
        s.append("]")
      end
      s
    end

  fun unsafe_diag(): DiagChain => _diag

type TxCommitVerdict is (CommitFailed | CommitAmbiguous | NotInTransaction)

primitive CommitFailed
  """
  Server rejected the commit; transaction rolled back.
  """
  fun string(): String val => "commit failed (rolled back by server)"

primitive CommitAmbiguous
  """
  Commit outcome unknown; reconnect required.
  """
  fun string(): String val => "commit result unknown (reconnect required)"

primitive NotInTransaction
  """
  Commit or rollback called without an active transaction.
  """
  fun string(): String val => "not in transaction"