Bind error

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
class val BindError
  """
  Error binding a parameter value.
  """
  let _kind: BindErrorKind
  let _param_index: ParamIndex
  let _diag: DiagChain

  new val create(
    kind': BindErrorKind,
    param_index': ParamIndex,
    diag': DiagChain = recover val Array[DiagRecord] end) =>
    _kind = kind'
    _param_index = param_index'
    _diag = diag'

  fun kind(): BindErrorKind => _kind
  fun param_index(): ParamIndex => _param_index

  fun string(): String iso^ =>
    recover iso
      String
        .> append("BindError: ")
        .> append(_kind.string())
        .> append(" (param ")
        .> append(_param_index.apply().string())
        .> append(")")
    end

  fun unsafe_diag(): DiagChain => _diag

type BindErrorKind is
  ( ParamIndexOutOfRange
  | ParamTooLarge
  | DriverRejected
  | BindStatementClosed
  | BindConnectionClosed
  )

primitive ParamIndexOutOfRange
  """
  Parameter index is zero or exceeds param count.
  """
  fun string(): String val => "index out of range"

primitive ParamTooLarge
  """
  Parameter value exceeds maximum size.
  """
  fun string(): String val => "parameter too large"

primitive DriverRejected
  """
  ODBC driver rejected the bind call.
  """
  fun string(): String val => "driver rejected"

primitive BindStatementClosed
  """
  Bind attempted on a closed statement.
  """
  fun string(): String val => "statement closed"

primitive BindConnectionClosed
  """
  Bind attempted after connection closed.
  """
  fun string(): String val => "connection closed"